home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 07 (1983-03)(Softdisk)(Side B).do / COMPILER DEMO PROGRAM 1.bas < prev    next >
BASIC Source File  |  1996-12-24  |  3KB  |  74 lines
  1. 0  HIMEM: 16383
  2. 30 U = 9:D = 3:E =  -16384:F =  -16368:G =  -16287:H =  -16286:Z = 127
  3. 100  POKE 768,173: POKE 769,48: POKE 770,192: POKE 771,136: POKE 772,208: POKE 773,4: POKE 774,198: POKE 775,7
  4. 110  POKE 776,240: POKE 777,8: POKE 778,202: POKE 779,208: POKE 780,246: POKE 781,166: POKE 782,6: POKE 783,76: POKE 784,0: POKE 785,03: POKE 786,96
  5. 200  TEXT : HOME : PRINT : POKE F,0
  6. 201  VTAB 1
  7. 210 X =  FRE(0)
  8. 220 A$ = "APPLE DEMONSTRATION PROGRAMS": GOSUB 2000: PRINT 
  9. 230  PRINT "    TO OPERATE A DEMONSTRATION,  TYPE"
  10. 240  PRINT "ITS NUMBER.  THEN TYPE THE KEY MARKED"
  11. 250  PRINT "'RETURN' AT THE RIGHT EDGE OF THE KEY-"
  12. 260  PRINT "BOARD.  TYPE THE 'RETURN' KEY TO STOP"
  13. 270  PRINT "ANY DEMONSTRATION.": PRINT : PRINT 
  14. 290  PRINT "1.";
  15. 300 A$ = "STANDARD COLOR NAMES": GOSUB 2000
  16. 310  PRINT "2.";
  17. 320 A$ = "STANDARD COLOR NUMBERS": GOSUB 2000
  18. 330  PRINT "3.";
  19. 340 A$ = "KALEIDOSCOPE": GOSUB 2000
  20. 350  PRINT "4.";
  21. 360 A$ = "SKETCHING SCREEN": GOSUB 2000
  22. 370  PRINT "5.";:A$ = "COMPILED 'COLOR DEMOSOFT'": GOSUB 2000
  23. 375  PRINT "6.";:A$ = "EXIT COMPILER DEMO": GOSUB 2000: PRINT 
  24. 380  INPUT "WHICH WOULD YOU LIKE?";A$
  25. 390  IF  LEN(A$) = 0  THEN  GOTO 200
  26. 395 N =  ASC(A$) -48
  27. 400  IF N <1  OR N >6  THEN  GOTO 200
  28. 410  ON N GOTO 500,600,700,800,4030,4040
  29. 450  IF  PEEK(E) <Z  THEN 450
  30. 460  GOTO 200
  31. 500  GOSUB 3000
  32. 510 A$ = "BMDPDGMLBOGPLYAW": GOSUB 4000: PRINT 
  33. 520 A$ = "LGBUGRBBRRRIGEQI": GOSUB 4000: PRINT 
  34. 530 A$ = "ATLRRELLWNENRLUT": GOSUB 4000: PRINT 
  35. 540 A$ = "KAUPNYUUNGYKNOAE": GOSUB 4000
  36. 550  GOTO 450
  37. 600  GOSUB 3000
  38. 610  FOR I = 0 TO 14  STEP 2
  39. 620  HTAB 2 *I +4: PRINT I;
  40. 630  NEXT I: PRINT 
  41. 640  FOR I = 1 TO 15  STEP 2
  42. 650  HTAB 2 *I +4: PRINT I;
  43. 660  NEXT I: PRINT : PRINT : GOTO 450
  44. 700  GR : HOME : FOR W = 3 TO 50: FOR I = 1 TO 19: FOR J = 0 TO 19:K = I +J: IF  PEEK(E) >Z  THEN 200
  45. 750  COLOR= J *3/(I +3) +I *W/12
  46. 760  PLOT I,K: PLOT K,I: PLOT 40 -I,40 -K: PLOT 40 -K,40 -I
  47. 770  PLOT K,40 -I: PLOT 40 -I,K: PLOT I,40 -K: PLOT 40 -K,I
  48. 780  NEXT J,I,W: GOTO 450
  49. 800  HOME :A$ = "USE THE GAME CONTROLS AND BUTTONS.": GOSUB 2000
  50. 810 A$ = "THE BUTTONS CLEAR THE TV AND CHANGE": GOSUB 2000
  51. 820 A$ = "THE DISPLAYED COLOR.  TRY ONE NOW.": GOSUB 2000
  52. 900  IF  PEEK(G) >Z  OR  PEEK(H) >Z  THEN 930
  53. 910  IF  PEEK(E) >Z  THEN 200
  54. 920  GOTO 900
  55. 930  HOME : GR 
  56. 940 P =  PDL(0):X =  INT(P/6): IF X >39  THEN X = 39
  57. 950 I =  PDL(1):Y =  INT(I/6): IF Y >39  THEN Y = 39
  58. 960 P =  INT((I +P)/2 +9): IF P >255  THEN P = 255
  59. 970  GOSUB 1500
  60. 980  VTAB 21: PRINT "X IS ";X;" ": PRINT "Y IS ";Y;" "
  61. 990  IF  PEEK(E) >Z  THEN 200
  62. 1000  IF  PEEK(G) >Z  THEN  GR 
  63. 1010  IF  PEEK(H) >Z  THEN U = (U +1)
  64. 1015  IF U = 16  THEN U = 0
  65. 1020  COLOR= U: PLOT X,Y: GOTO 940
  66. 1500  POKE 6,P: POKE 7,D: CALL 768: RETURN 
  67. 2000  HTAB ((40 - LEN(A$))/2 +1): PRINT A$: PRINT : RETURN 
  68. 3000  GR : FOR I = 0 TO 31: COLOR= I/2: VLIN 0,39 AT I +3: NEXT I
  69. 3010  COLOR= 5: VLIN 0,39 AT 2: VLIN 0,39 AT 35: HLIN 2,35 AT 0: HLIN 2,35 AT 39: RETURN 
  70. 4000  FOR I = 1 TO  LEN(A$)
  71. 4010  HTAB 2 *I +2: PRINT  MID$ (A$,I,1);
  72. 4020  NEXT I: RETURN 
  73. 4030  CALL 16384
  74. 4040  TEXT : HOME : PRINT  CHR$(4)"RUN MENU":